[Libguestfs] [PATCH 4/4] sysprep: add FreeIPA offline unenrollment (RHBZ#1789592)
This new operation unenrolls the guest from a FreeIPA server offline, by
removing the configuration files and certificates.
Thanks to Christian Heimes for the hints.
---
sysprep/Makefile.am | 1 +
sysprep/sysprep_operation_unenroll_freeipa.ml | 65 +++++++++++++++++++
2 files changed, 66 insertions(+)
create mode 100644 sysprep/sysprep_operation_unenroll_freeipa.ml
diff --git a/sysprep/Makefile.am b/sysprep/Makefile.am
index 451a3478f..30254c717 100644
--- a/sysprep/Makefile.am
+++ b/sysprep/Makefile.am
@@ -66,6 +66,7 @@ operations = \
sssd_db_log \
tmp_files \
udev_persistent_net \
+ unenroll_freeipa \
user_account \
utmp yum_uuid
diff --git a/sysprep/sysprep_operation_unenroll_freeipa.ml
b/sysprep/sysprep_operation_unenroll_freeipa.ml
new file mode 100644
index 000000000..5dd2bcc61
--- /dev/null
+++ b/sysprep/sysprep_operation_unenroll_freeipa.ml
@@ -0,0 +1,65 @@
+(* virt-sysprep
+ * Copyright (C) 2020 Red Hat Inc.
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with this program; if not, write to the Free Software Foundation, Inc.,
+ * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
+ *)
+
+open Sysprep_operation
+open Common_gettext.Gettext
+
+module G = Guestfs
+
+let unenroll_freeipa_perform (g : Guestfs.guestfs) root side_effects =
+ let typ = g#inspect_get_type root in
+ if typ = "linux" then (
+ (* Simple paths with no side effects. *)
+ let paths = [ "/etc/ipa/ca.crt";
+ "/etc/ipa/default.conf";
+ "/var/lib/ipa-client/sysrestore/*";
+ "/var/lib/ipa-client/pki/*" ] in
+ let paths = List.concat (List.map Array.to_list (List.map g#glob_expand paths)) in
+ List.iter (
+ fun filename ->
+ try g#rm filename with G.Error _ -> ()
+ ) paths;
+
+ (* Certificates in the system CA store. *)
+ let certs = [ "/etc/pki/ca-trust/source/anchors/ipa-ca.crt";
+ "/usr/local/share/ca-certificates/ipa-ca.crt";
+ "/etc/pki/ca-trust/source/ipa.p11-kit" ] in
+ List.iter (
+ fun filename ->
+ try
+ g#rm filename;
+ side_effects#update_system_ca_store ()
+ with
+ G.Error _ -> ()
+ ) certs
+ )
+
+let op = {
+ defaults with
+ name = "unenroll-freeipa";
+ enabled_by_default = true;
+ heading = s_"Offline unenroll the guest from FreeIPA";
+ pod_description = Some (s_"\
+Unenroll the guest from FreeIPA, reverting and cleaning up the local
+server settings only, without interacting with the FreeIPA server.
+
+This operation does not run C<ipa-client>.");
+ perform_on_filesystems = Some unenroll_freeipa_perform;
+}
+
+let () = register_operation op
--
2.25.4